zoho.com for other purpose.
ZHUO QL (KDr2), http://kdr2.com
---
### Author:  [@effbiae](https://forum.kx.com/u/effbiae)
#### Post date: [October 23, 2016, 1:32am UTC](https://forum.kx.com/t/functions-and-adverbs/11312/3 "2016-10-23T01:32:00Z")
I hadn’t intended for this to be so wordy - apologies.
Parsing…
the core grammar is: E:E;e|e e:nve|te| t:n|v v:tA|V n:t[E]|(E)|{E}|N
the relevant parts to adverb and application are:
v:tA (a verb is a term followed by an adverb.
n:t[E] (a term followed by a ‘[’)
1. Why does this work?
{[x;y] x+y}/[1;2]
3
this parses as t[E] where t is a verb (tA) where the lambda is a term (t)
q)0N!parse"{[x;y] x+y}/[1;2]";
((/;{[x;y] x+y});1;2)
t is a verb that can accept one or two arguments. two arguments are provided as E (1 and 2) and is equivalent to the juxtapose
q)0N!parse"1{[x;y] x+y}/2";
((/;{[x;y] x+y});1;2)
note that the first arg in the call is the "x" argument (left) and the second is "y"
1. And this does not.
0{[x;y] x+y}/[1;2]
this expression is equivalent to:
0 ( 1{[x;y] x+y}/2 )
q)0N!parse"0{[x;y] x+y}/[1;2]";
(0;((/;{[x;y] x+y});1;2))
that is, 0(6) - and the function “zero” does not like integers: http://code.kx.com/wiki/Reference/Zero
it can be thought that kdb+ evaluates from right to left of “right of left”, but it is actually the parsing rules that cause the right of left “evaluation”.
considering e:nve|te|e| and “1-2+3”. using nve: (1-“2+3”) -\> (1-(2+“3”)) -\> (1-(2+(3))) (last step by e:te|)
the actual tree is:
q)0N!parse"1-2+3";
(-;1;(+;2;3)) /verb followed by arguments - recursively evaluated
1. And this does not.
0 {[x;y] x+y}/[1 2 3]
'type
we know that {[x;y] x+y}/[1 2 3] evaluates to 6. so the expression reduces to 0(6).
as soon as you use the n:t[E] syntax, the t expression becomes a noun and there is no way to pass an x/left argument to a noun by using juxtaposition (only verbs allow arguments to their left - oh, and an adverb takes a single term to it’s left)
1. This does not work as well AND it produces different error message…
0 {[x;y] x+y}/ [1 2 3 4 5]
'length
this one seems to be a curiosity - 0 must have at least two constraints (type and length) and the length constraint isn’t violated until an integer argument exceeds 9. the length constraint is checked first and so when length constraint is violated… that’s my guess.
---
### Author:  [@sieber](https://forum.kx.com/u/sieber)
#### Post date: [October 25, 2016, 10:45am UTC](https://forum.kx.com/t/functions-and-adverbs/11312/4 "2016-10-25T10:45:00Z")
> The confusing part follows:
>
> 1. Why does this work?
>
> {[x;y] x+y}/[1;2]
>
> 3
{[x;y]x+y} is equivalent to {x+y},
{x+y}/ produces a “new” function which has one OR two arguments.
q allows you to call a funciton with two arguments via function[param1;param2] OR in some cases (for example + or - and THIS NEW function) via param1 function param2 (=\> example 1+3)
If used with two arguments the first one is just the first step in the “over” (/) reduce.
so {x+y}/[1;2] is the same as 1{x+y}/enlist 2 which is the same as {x+y}/[1 2]…
> 1. And this does not.
>
> 0 {[x;y] x+y}/[1;2]
now you try to call the new function with 3 parameters: first 0, second 1 third 2. As the “new” function has only max 2 arguments, you get an error
> 1. Why does this work?
>
> 0 {[x;y] x+y}/1 2 3
>
> 6
you call it again with two arguments: first 0 second list of 1 2 and 3
> 1. And this does not.
>
> 0 {[x;y] x+y}/[1 2 3]
>
> 'type
here you call the new function with one parameter: 1 2 3. This results 6. Now you apply 6 to 0. (same as 0@6 or 0[6], ..) which gives a type error
> 1. This does not work as well AND it produces different error message…
>
> 0 {[x;y] x+y}/ [1 2 3 4 5]
>
> 'length
>
> I would absolutely love to know why equation (7) and equation (8) produce different error messages.
cant tell you why you get a different error. But you call 0@15 here which produces a length error 0@6 produces type error. no idea why..
I think you should read the function part in the tutorial: [http://code.kx.com/wiki/JB:QforMortals2/primitive\_operations#Introduction\_to\_Functions](http://code.kx.com/wiki/JB:QforMortals2/primitive%5C_operations#Introduction%5C_to%5C_Functions)
In q/k you have many variants on how you can execute a function. It is fundamentally important to understand this
regards, Markus
---
### Author:  [@VA1](https://forum.kx.com/u/VA1)
#### Post date: [October 26, 2016, 12:37pm UTC](https://forum.kx.com/t/functions-and-adverbs/11312/5 "2016-10-26T12:37:00Z")
Very detailed answers, thank you very much I shall go through the explanations today.